home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 051-075 / disk_055 / newstartups / twstartup.asm < prev    next >
Assembly Source File  |  1992-05-06  |  11KB  |  460 lines
  1. * ==========================
  2. * amiga.dev/programs #12, from cscheppner, 11195 chars, Tue Feb 24 17:54:45 1987
  3. * --------------------------
  4. * TITLE:  TWstartup.asm --- Modified Astartup, opens Amiga stdio under WB
  5.  
  6. *******************************************************************
  7. * TWStartup.asm  - Amiga Startup opens stdio window on WB startup *
  8. *                  using TWspec defined in application            *
  9. *       example:   char TWspec[] = "CON:30/30/200/150/MyProgram"; *
  10. *                   ( OR  char TWspec = "";  for no window )      *
  11. *                                                                 *
  12. * Modified be C. Scheppner (08/03/86) from the following source:  *
  13. ******************************************************************* 
  14. *                                                                 *
  15. *   C Program Startup/Exit (Combo Version: CLI and WorkBench)     *
  16. *                                                                 *
  17. *******************************************************************
  18. *
  19. * Source Control:
  20. * --------------
  21. *
  22. * $Header: startup.asm,v 1.1 86/08/25 12:50:07 root Exp $
  23. *
  24. * $Locker: root $
  25. *
  26. * $Log:   startup.asm,v $
  27. * Revision 1.1  86/08/25  12:50:07  root
  28. * Initial revision
  29. *
  30. * Revision 33.6  86/06/12  10:34:36  neil
  31. * changed so any version of dos is OK
  32. * 
  33. * Revision 33.5  86/06/11  19:03:47  neil
  34. * fixed CloseLibrary if open of dos failed
  35. * 
  36. * Revision 33.4  86/06/09  16:48:59  neil
  37. * now processes escapes also
  38. * 
  39. * Revision 33.3  86/06/09  16:18:12  neil
  40. * another checkpoint -- quoted strings now work
  41. * 
  42. * Revision 1.1  85/11/23  13:49:01  neil
  43. * Initial revision
  44. * 
  45. *
  46. ************************************************************************
  47.  
  48.  
  49. ******* Included Files *************************************************
  50.  
  51.    INCLUDE "exec/types.i"
  52.    INCLUDE "exec/alerts.i"
  53.    INCLUDE "exec/nodes.i"
  54.    INCLUDE "exec/lists.i"
  55.    INCLUDE "exec/ports.i"
  56.    INCLUDE "exec/libraries.i"
  57.    INCLUDE "exec/tasks.i"
  58.    INCLUDE "libraries/dos.i"
  59.    INCLUDE "libraries/dosextens.i"
  60.    INCLUDE "workbench/startup.i"
  61.  
  62.  
  63. ******* Imported *******************************************************
  64.  
  65. xlib   macro
  66.    xref   _LVO\1
  67.    endm
  68.  
  69.    xref   _AbsExecBase
  70.    xref   _Input
  71.    xref   _Output
  72.  
  73.    xref   _main         ; C code entry point
  74.  
  75.    xref   _TWspec       ; con: spec in application for WB stdio window
  76.  
  77.    xlib   Alert
  78.    xlib   FindTask
  79.    xlib   Forbid
  80.    xlib   GetMsg
  81.    xlib   OpenLibrary
  82.    xlib   CloseLibrary
  83.    xlib   ReplyMsg
  84.    xlib   Wait
  85.    xlib   WaitPort
  86.  
  87.    xlib   CurrentDir
  88.    xlib   Open
  89.    xlib   Close
  90.  
  91. ******* Exported *******************************************************
  92.  
  93.    xdef   _SysBase
  94.    xdef   _DOSBase
  95.  
  96.    xdef   _errno
  97.    xdef   _stdin
  98.    xdef   _stdout
  99.    xdef   _stderr
  100.  
  101.    xdef   _exit         ; standard C exit function
  102.    xdef   _WBenchMsg
  103.  
  104.  
  105. callsys   macro
  106.    CALLLIB   _LVO\1
  107.    endm
  108.  
  109.  
  110. ************************************************************************
  111. *
  112. *   Standard Program Entry Point
  113. *
  114. ************************************************************************
  115. *
  116. *   main (argc, argv)
  117. *      int  argc;
  118. *      char *argv[]; 
  119. *
  120. ************************************************************************
  121.  
  122. startup:            ; reference for Wack users
  123.       move.l   sp,initialSP   ; initial task stack pointer
  124.       move.l   d0,dosCmdLen
  125.       move.l   a0,dosCmdBuf
  126.  
  127.       ;------ get Exec's library base pointer:
  128.       move.l   _AbsExecBase,a6
  129.       move.l   a6,_SysBase
  130.  
  131.       ;------ get the address of our task
  132.       suba.l   a1,a1
  133.       callsys   FindTask
  134.       move.l   d0,a4
  135.  
  136.       ;------ are we running as a son of Workbench?
  137.       tst.l   pr_CLI(A4)
  138.       beq   fromWorkbench
  139.  
  140. ;=======================================================================
  141. ;====== CLI Startup Code ===============================================
  142. ;=======================================================================
  143. fromCLI:
  144.       ;------   attempt to open DOS library:
  145.       bsr   openDOS
  146.  
  147.       ;------ find command name:
  148.       suba.l   a0,a0
  149.       move.l   pr_CLI(a4),d0
  150.       lsl.l   #2,d0      ; bcpl pointer conversion
  151.       move.l   cli_CommandName(a0,d0.l),d0
  152.       lsl.l   #2,d0      ; bcpl pointer conversion
  153.  
  154.       ;------ create buffer and array:
  155.       movem.l   a2/a3,-(sp)
  156.       lea   argvBuffer,a2
  157.       lea   argvArray,a3
  158.  
  159.       ;------ fetch command name:
  160.       move.l   d0,a0
  161.       moveq.l   #0,d0
  162.       move.b   (a0)+,d0   ; size of command name
  163.       clr.b   0(a0,d0.l)   ; terminate the string
  164.       move.l   a0,(a3)+
  165.  
  166.       ;------   collect parameters:
  167.       move.l   dosCmdLen,d0
  168.       move.l   dosCmdBuf,a0
  169.  
  170.       ;------ null terminate the string, eat trailing garbage
  171.       lea   0(a0,d0.l),a1
  172. stripjunk:
  173.       cmp.b   #' ',-(a1)
  174.  
  175.       ;-- jimm: 8/25/86: per kodiak's recommendation
  176.       ; bls.s   stripjunk
  177.       dbhi   D0,stripjunk
  178.  
  179.       clr.b   1(a1)
  180.  
  181. newarg:
  182.       ;------ skip spaces
  183.       move.b   (a0)+,d1
  184.       beq.s   parmExit
  185.       cmp.b   #' ',d1
  186.       beq.s   newarg
  187.       cmp.b   #9,d1         ; tab
  188.       beq.s   newarg
  189.  
  190.       ;------ push address of the next parameter
  191.       move.l   a2,(a3)+
  192.  
  193.       ;------ process quotes
  194.       cmp.b   #'"',d1
  195.       beq.s   doquote
  196.  
  197.       ;------ copy the parameter in
  198.       move.b   d1,(a2)+
  199.  
  200. nextchar:
  201.       ;------ null termination check
  202.       move.b   (a0)+,d1
  203.       beq.s   parmExit
  204.       cmp.b   #' ',d1
  205.       beq.s   endarg
  206.  
  207.       move.b   d1,(a2)+
  208.       bra.s   nextchar
  209.  
  210. endarg:
  211.       clr.b   (a2)+
  212.       bra.s   newarg
  213.  
  214. doquote:
  215.       ;------ process quoted strings
  216.       move.b   (a0)+,d1
  217.       beq.s   parmExit
  218.       cmp.b   #'"',d1
  219.       beq.s   endarg
  220.  
  221.       ;------ '*' is the BCPL escape character
  222.       cmp.b   #'*',d1
  223.       bne.s   addquotechar
  224.  
  225.       move.b   (a0)+,d1
  226.       cmp.b   #'N',d1
  227.       beq.s   1$
  228.       cmp.b   #'n',d1
  229.       bne.s   2$
  230.  
  231. 1$:
  232.       ;------ got a *N -- turn into a newline
  233.       moveq   #10,d1
  234.       bra.s   addquotechar
  235.  
  236. 2$:
  237.       cmp.b   #'E',d1
  238.       beq.s   3$
  239.       cmp.b   #'e',d1
  240.       bne.s   addquotechar
  241.  
  242. 3$:
  243.       ;------ got a *E -- turn into a escape
  244.       moveq   #27,d1
  245.  
  246. addquotechar:
  247.       move.b   d1,(a2)+
  248.       bra.s   doquote
  249.  
  250. parmExit:
  251.       ;------ all done -- null terminate the baby
  252.       clr.b   (a2)
  253.       clr.l   (a3)
  254.  
  255.       ;------ compute the # of arguments
  256.       move.l   #dosCmdBuf,d0
  257.       sub.l   a3,d0
  258.       not.l   d0
  259.       lsr.l   #2,d0
  260.  
  261.       movem.l   (sp)+,a2/a3
  262.       pea   argvArray
  263.       move.l   d0,-(sp)
  264.  
  265.  
  266. *
  267. *  The above code relies on the end of line containing a control
  268. *  character of any type, i.e. a valid character must not be the
  269. *  last.  This fact is ensured by DOS.
  270. *
  271.       
  272.  
  273.       ;------ get standard input handle:
  274.       jsr   _Input
  275.       move.l   d0,_stdin
  276.  
  277.       ;------ get standard output handle:
  278.       jsr   _Output
  279.       move.l   d0,_stdout
  280.       move.l   d0,_stderr
  281.  
  282.       ;------ call C main entry point
  283.       jsr   _main
  284.  
  285.       ;------ return success code:
  286.       moveq.l   #0,D0
  287.       move.l   initialSP,sp   ; restore stack ptr
  288.       rts
  289.  
  290. ;=======================================================================
  291. ;====== Workbench Startup Code =========================================
  292. ;=======================================================================
  293. fromWorkbench:
  294.       ;------ open the DOS library:
  295.       bsr   openDOS
  296.  
  297.       ;------ we are now set up.  wait for a message from our starter
  298.       bsr   waitmsg
  299.  
  300.       ;------ save the message so we can return it later
  301.       move.l   d0,_WBenchMsg
  302.  
  303.       ;------ push the message on the stack for wbmain
  304.       move.l   d0,-(SP)
  305.       clr.l   -(SP)      indicate: run from Workbench
  306.  
  307.       ;------ get the first argument
  308.       move.l   d0,a2
  309.       move.l   sm_ArgList(a2),d0
  310.       beq.s   docons
  311.  
  312.       ;------ and set the current directory to the same directory
  313.       move.l   _DOSBase,a6
  314.       move.l   d0,a0
  315.       move.l   wa_Lock(a0),d1
  316.       callsys   CurrentDir
  317.  
  318. * ==============================================
  319. * ============ Opens stdio window ==============
  320. * ==============================================
  321.  
  322. docons: 
  323.       lea.l    _TWspec,a0
  324.       cmp.b    #0,(a0)           No window if TWspec is null string
  325.       beq.s    domain
  326.  
  327.    ;------ open up the file
  328.       move.l   a0,d1
  329.       move.l   #MODE_OLDFILE,d2 
  330.       move.l   _DOSBase,a6
  331.       callsys   Open 
  332.  
  333.    ;------ set the C input and output descriptors 
  334.       cmp.l    #0,d0
  335.       beq.s    exit2
  336.       move.l   d0,_stdin 
  337.       move.l   d0,_stdout 
  338.       move.l   d0,_stderr 
  339.  
  340.    ;------ set the console task (so Open( "*", mode ) will work 
  341.    ;   waitmsg has left the task pointer in A4 for us 
  342.       move.l   d0,pr_CIS(A4)
  343.       move.l   d0,pr_COS(A4)
  344.       lsl.l    #2,d0 
  345.       move.l   d0,a0 
  346.       move.l   fh_Type(a0),pr_ConsoleTask(A4) 
  347.  
  348.  
  349. domain: 
  350.       jsr   _main
  351.       moveq.l   #0,d0      Successful return code
  352.       bra.s   exit2
  353.  
  354.  
  355. ************************************************************************
  356. *
  357. *   C Program Exit Function
  358. *
  359. ************************************************************************
  360. *
  361. *  Warning: this function really needs to do more than this.
  362. *
  363. ************************************************************************
  364.  
  365. _exit:
  366.       move.l   4(SP),d0   ; extract return code
  367. exit2:
  368.    ;------ Close ToolWin if we have one:
  369.       tst.l   _WBenchMsg 
  370.       beq.s   noTW
  371.       move.l  _stdin,d1
  372.       bmi.s   noTW
  373.       move.l  _DOSBase,a6
  374.       callsys Close
  375.  
  376. noTW:
  377.       move.l  initialSP,SP   ; restore stack pointer
  378.       move.l   d0,-(SP)   ; save return code
  379.  
  380.       ;------ close DOS library:
  381.       move.l   _AbsExecBase,A6
  382.       move.l   _DOSBase,d0
  383.       beq.s   1$
  384.       move.l   d0,a1
  385.       callsys   CloseLibrary
  386. 1$:
  387.  
  388.       ;------ if we ran from CLI, skip workbench cleanup:
  389.       tst.l   _WBenchMsg
  390.       beq.s   exitToDOS
  391.  
  392.       ;------ return the startup message to our parent
  393.       ;------   we forbid so workbench can't UnLoadSeg() us
  394.       ;------   before we are done:
  395.       callsys Forbid
  396.       move.l   _WBenchMsg,a1
  397.       callsys   ReplyMsg
  398.  
  399.       ;------ this rts sends us back to DOS:
  400. exitToDOS:
  401.       move.l   (SP)+,d0
  402.       rts
  403.  
  404.  
  405. ;-----------------------------------------------------------------------
  406. noDOS:
  407.       ALERT   (AG_OpenLib!AO_DOSLib)
  408.       moveq.l   #100,d0
  409.       bra.s   exit2
  410.  
  411.  
  412. ;-----------------------------------------------------------------------
  413. ; This routine gets the message that workbench will send to us
  414. ; called with task id in A4
  415.  
  416. waitmsg:
  417.       lea   pr_MsgPort(A4),a0     * our process base
  418.       callsys   WaitPort
  419.       lea   pr_MsgPort(A4),a0     * our process base
  420.       callsys GetMsg
  421.       rts
  422.  
  423. ;-----------------------------------------------------------------------
  424. ;  Open the DOS library:
  425.  
  426. openDOS
  427.       lea   DOSName(pc),A1
  428.       moveq   #0,d0
  429.       callsys OpenLibrary
  430.       move.l   D0,_DOSBase
  431.       beq   noDOS
  432.       rts
  433.  
  434. DOSName      DOSNAME
  435.  
  436. ************************************************************************
  437.  
  438.    DATA
  439.  
  440. ************************************************************************
  441.  
  442. VerRev      dc.w   33,1
  443.  
  444. _SysBase   dc.l   0
  445. _DOSBase   dc.l   0
  446.  
  447. _errno      dc.l   0
  448. _stdin      dc.l   -1
  449. _stdout      dc.l   -1
  450. _stderr      dc.l   -1
  451.  
  452. initialSP   dc.l   0
  453. _WBenchMsg   dc.l   0
  454.  
  455. dosCmdLen   dc.l   0
  456. dosCmdBuf   dc.l   0
  457.  
  458. argvArray   ds.l   32
  459. argvBuffer   ds.b   256
  460.